Option Explicit

Sub StocksAnalysis()

Dim ws As Worksheet

Dim lastRow As Long

Dim ticker As String

Dim nextRowTicker As String

Dim openingPrice As Double

Dim closingPrice As Double

Dim yearlyChange As Double

Dim changeFraction As Double

Dim totalVolume As LongLong

Dim inputRow As Long

Dim summaryRow As Long

Dim greatestIncrease As Double

Dim greatestDecrease As Double

Dim greatestVolume As Double

Dim greatestIncreaseTicker As String

Dim greatestDecreaseTicker As String

Dim greatestVolumeTicker As String

For Each ws In ThisWorkbook.Worksheets

lastRow = ws.Cells(Rows.Count, 1).End(xlUp).Row

' Set up summary table headers

ws.Cells(1, 9).Value = "Ticker"

ws.Cells(1, 10).Value = "Yearly Change"

ws.Cells(1, 11).Value = "Percentage Change"

ws.Cells(1, 12).Value = "Total Volume"

ws.Cells(2, 14).Value = "Greatest Percentage Increase"

ws.Cells(3, 14).Value = "Greatest Percentage Decrease"

ws.Cells(4, 14).Value = "Greatest Total Volume"

greatestIncrease = 0

greatestDecrease = 0

greatestVolume = 0

summaryRow = 2

openingPrice = ws.Cells(2, 3).Value

totalVolume = 0

' Loop through all the stocks

For inputRow = 2 To lastRow

totalVolume = totalVolume + ws.Cells(inputRow, 7).Value

ticker = ws.Cells(inputRow, 1).Value

nextRowTicker = ws.Cells(inputRow + 1, 1).Value

If ticker <> nextRowTicker Then

'Last row of current stock

'Input

closingPrice = ws.Cells(inputRow, 6).Value

' Calculations

yearlyChange = closingPrice - openingPrice

If openingPrice <> 0 Then

changeFraction = (yearlyChange / openingPrice)

Else

changeFraction = 0

End If

If changeFraction > greatestIncrease Then

greatestIncrease = changeFraction

greatestIncreaseTicker = ticker

End If

If changeFraction < greatestDecrease Then

greatestDecrease = changeFraction

greatestDecreaseTicker = ticker

End If

If totalVolume > greatestVolume Then

greatestVolume = totalVolume

greatestVolumeTicker = ticker

End If

' Output

ws.Cells(summaryRow, 9).Value = ticker

ws.Cells(summaryRow, 10).Value = yearlyChange

If yearlyChange >= 0 Then

ws.Cells(summaryRow, 10).Interior.ColorIndex = 4 ' Green color

Else

ws.Cells(summaryRow, 10).Interior.ColorIndex = 3 ' Red color

End If

ws.Cells(summaryRow, 11).Value = FormatPercent(changeFraction)

ws.Cells(summaryRow, 12).Value = totalVolume

' Prepare for next stock

summaryRow = summaryRow + 1

openingPrice = ws.Cells(inputRow + 1, 3).Value

totalVolume = 0

End If

Next inputRow

' Auto-fit the columns in the summary table

ws.Columns("I:K").AutoFit

ws.Range("O2").Value = greatestIncreaseTicker

ws.Range("O3").Value = greatestDecreaseTicker

ws.Range("O4").Value = greatestVolumeTicker

ws.Range("P2").Value = greatestIncrease

ws.Range("P2").NumberFormat = "0.00%"

ws.Range("P3").Value = greatestDecrease

ws.Range("P3").NumberFormat = "0.00%"

ws.Range("P4").Value = greatestVolume

Next ws

End Sub